initial version

flake largely copied from the new birdtown-visit-counter

module.nix

@@ -0,0 +1,66 @@
+inputs:
+{ config, lib, pkgs, ... }:
+let
+  inherit (pkgs.stdenv.hostPlatform) system;
+  cfg = config.services.birdtown-leaderboard;
+  inherit (lib) types mkOption mkIf;
+  package = inputs.self.packages."${system}".default;
+in {
+  options.services.birdtown-leaderboard = {
+    enable = mkOption {
+      type = types.bool;
+      default = false;
+    };
+    listenPort = mkOption {
+      type = types.int;
+      default = 11567;
+    };
+  };
+  config = mkIf cfg.enable {
+    users.users.birdtown-leaderboard = {
+      group = "birdtown-leaderboard";
+      home = "/var/lib/birdtown-leaderboard";
+      isSystemUser = true;
+      createHome = true;
+    };
+    users.groups.birdtown-leaderboard = { };
+
+    systemd.services.birdtown-leaderboard = {
+      after = [ "network.target" ];
+      wantedBy = [ "multi-user.target" ];
+      serviceConfig = {
+        ExecStart =
+          "${package}/bin/birdtown-leaderboard -addr :${toString  cfg.listenPort} -file scores.json";
+        User = "birdtown-leaderboard";
+        Group = "birdtown-leaderboard";
+        WorkingDirectory = "/var/lib/birdtown-leaderboard";
+      };
+    };
+
+    systemd.timers.birdtown-leaderboard-saver = {
+      wantedBy = [ "timers.target" ];
+      timerConfig = {
+        OnBootSec = "10m";
+        OnUnitActiveSec = "10m";
+        Unit = "birdtown-leaderboard-saver.service";
+      };
+    };
+
+    systemd.services.birdtown-leaderboard-saver = {
+      script = ''
+        set -eu
+        if ${pkgs.curl}/bin/curl http://localhost:${toString cfg.listenPort}/all > scores-new.json; then
+           cp scores-new.json "$(date +"%Y-%m-%d-%H-%M").json"
+           mv scores-new.json scores.json
+           ${pkgs.findutils}/bin/find . -ctime +10 -delete
+         fi
+      '';
+      serviceConfig = {
+        Type = "oneshot";
+        User = "birdtown-leaderboard";
+        Group = "birdtown-leaderboard";
+        WorkingDirectory = "/var/lib/birdtown-leaderboard";
+      };
+    };
+  };
+}